acenetglobal.com.au - Web hosting and Domain name registration services. Acenet Global prides itself on being a small company that can provide personalised support to its customers

Email Login

Call: 1300 859 985

Form Mail

This script allows you to send information from a web form to an email address. More examples can be found off the Example page.

Quick Instructions

First you will need a web form. If you have not created one already you can use smart-upload.htm. You also view our script as a text file smart-upload.txt
Create a file called mail.asp on your web site and copy the contents of the text area below into that file. You also view our script as a text file smart-upload.txt
Point your web form to the newly created file mail.asp
Change the html <form> tag to include the encoding type "multipart/form-data".
<form name="enctype="multipart/form-data"

<%  
'========================================================
'   JMail with SmartUp example script. V 0.0.1 - beta
'========================================================
' JMail with SmartUp example script. 
' This script can be used to send an email from your 
' contacts page or any other webpage of your choosing. 
' This script will also attach a file of your choosing.
' Please remember to use the details that are relavent 
' to your domain. 
'
' This page will only process information when hosted 
' on a server that supports asp otherwise you will see 
' these comments instead.
'
'-------------------------------------------------------
' Some variables required for processing this script
'-------------------------------------------------------
'
   Dim Item
   Dim YourName
   Dim YourEmailAddress
   Dim From
   Dim Subject 
   Dim Body
   Dim Jmail
   Dim MailServer
   Dim FinishPage      
   Dim mySmartUpload 'declare the SmartUpload component
   Dim File 'declare the file to upload
                           Dim tempLocation ' the folder that will store your temporary files. 
   Dim filename 'Temp filename
   Dim fs
   Dim f
   Dim FileNameTitle
   Dim ContentType
   Dim newline         
       newline = chr(13) + chr(10)

On Error resume Next ' Exceptions are now being handled
    
    ' Initialise the objects                      
    Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")
    ' Create a SmartUpload object
		
    ' limit the total upload to 200 Kb, larger sizes are not recommended.
		' -- We have tested the email script and have found that files up to 2meg seem to work okay. 
    ' Limit set to:	
    
    mySmartUpload.MaxFileSize = 200000
    mySmartUpload.TotalMaxFileSize = 200000
    
    ' This is a basic list of usable files. It is also ways a good idea to 
    ' to block pif and bat files. It is strongly recommended to block .exe 
    ' files as well. For security reasons you should limit the types of files 
		' allowed to those that you really need to use.
    ' Limit the file extensions to:
    
    mySmartUpload.AllowedFilesList="gif,jpg,doc,txt,zip,htm,html"
    mySmartUpload.DeniedFilesList="exe,pif,bat"

'Upload the selected file to the server
    mySmartUpload.Upload

Set JMail = Server.CreateObject("JMail.SMTPMail")
    ' Initialise JMail object with the details provided above.
                                                 
'-------------------------------------------------------
' In order for this script to work you will need to 
' fill in the details below. 
'
' This script is designed to have information sent FROM 
' a web form TO this page for processing. The information 
' is sent via POST. You can use the example webform as a 
' template if you are unsure on how to setup this up.
' 
' If you want a valid senders email address you can 
' included a text box in your form labelled as "EmailAddress". 
' See the script-example\webform.htm site for more details.
'
' NOTES: If you are in doubt about what to put in any of the 
' fields then you can leave it blank. This script will work 
' straight of the shelf. If you leave the details blank the
' script will use the following as defaults.
' 
' This script will contact the webserver to find yourdomain name
' instead of example.com
' 
' YourName = "" ' not required to send an email message.
' YourEmailAddress = "postmaster@example.com"
' From = "webform@example.com"
' MailServer = "mail.example.com"
' Subject = "" ' not required but annoying not to have.

'-------------------------------------------------------

'The name in front of the email address. 
'* This field is optional and can be left blank.

'Example:    YourName = "Fred Smith"

YourName = ""

'Type in your email address. This is the address of the 
'person that you want to recieve this email.
'By default this script will email 
' webform@yourdomain.com at your domain.

' Example: YourEmailAddress = "fredsmith@example.com"

YourEmailAddress = ""

' Please specify a correct address for the email Sender
' or From address. This Field is optional and can be left blank.
'
' Example: YourEmailAddress = "fredsmith@example.com"

From = ""  
         
' ********************************
' NOTE: 
' If no information is entered above the script will attempt to 
' to look for a form field called EmailAddress otherwise it will use
' "postmaster" at the domain that this script is hosted on.
' ********************************

' Type in your mail server address. If you do not know your 
' your mail server try leaving this field empty.

' Example: MailServer = "mail.example.com"

MailServer = ""

' Subject line for the email.

' Example: Subject = "Contact Form"

Subject = "Contact Form"

' We will now need to select a location to store the temporary files on the web server.
' This directory will be located relative to your website and not the file server.
' You may need to contact Acenet or your service provider in order to setup this directory. 
'
' Example. tempLocation = "temp" (this indicates the file "www.example.com/temp/")

tempLocation = "temp"

' Type in the name of the page you want to display after 
' the form has been processed and emailed.
' *This Field is optional and can be left blank.

FinishPage = ""

'---------------------------------------------
' That's it. The remainer of this file is used 
' for the processing of your email. 
' Please ensure that you have entered valid 
' information in the fields above.
'
' Comments have been included below if you
' would like find out more about this script
' works.
'---------------------------------------------

'
' This will extract every form element from the 
' submitting web form and add them to the body of the 
' message with the label name and it's value on seperate
' lines (eg. Label:Value)

' Check that the from address is valid, otherwise use
' webform@example.com This code will check that 
' we have a 'From' address. Preferable use a textbox 
' in your web form with the label name="EmailAddress"
' example: <input name="EmailAddress" type="text" size="32">
' If you have used an "EmailAddress" field in your form 
' you need to ensure that the 'From' variable is left blank.

If From = "" Then 
     If Trim(mySmartUpload.Form("EmailAddress")) <> "" Then 
      From = Trim(mySmartUpload.Form("EmailAddress"))
     Else                    
      From = "webform@" & Replace(Request.ServerVariables("SERVER_NAME"), "www.","")
     End if      
    End if

If MailServer = "" Then 
     JMail.ServerAddress = "mail." & Replace(Request.ServerVariables("SERVER_NAME"), "www.","")
    Else
     JMail.ServerAddress = MailServer
    End if
                
    If YourEmailAddress = "" then
     YourEmailAddress = "postmaster@" & Replace(Request.ServerVariables("SERVER_NAME"), "www.","")
    End if

If YourName <> "" then 
         YourEmailAddress = YourName & " " & YourEmailAddress ' don't forget the space!
    End If

' Now we check the files being uploaded before writing them to disk.
                ' This section of code will cause errors if you do not have the correct
                ' file permissions set. Please contact your hosting provider for more details.
                ' map the path we are using.
                
                For each File In mySmartUpload.Files    
      If not File.IsMissing then

File.SaveAs("/" & tempLocation & "/" & File.FileName)    ' this can cause errors if two documents are labelled the same

' TODO: impliment script using session.sessionID
                                                 
       JMail.AddAttachment Server.MapPath("/" & tempLocation) & "\" & File.FileName              
                         FileNameTitle = File.FileName
                   ContentType = File.ContentType                  
      End If
                Next 
  
    ' error managment. Error messages are included with the email.
    If not Err.Number = 0 then          
                 body = body & "There were errors with the attachment" & newline
                 body = body & "Please contact the client and request they resend the file." & newline
                 body = body & "Error : " & Err.description & newline             
                 body = body & JMail.ErrorMessage & newline                      
    End if

' This will extract every form element from the 
    ' submitting web form and add them to the body of the 
    ' message with the label name and it's value on seperate
    ' lines (eg. Label:Value)

For each item In mySmartUpload.Form
  
     '  Select each value of the current item
  
        For each value In mySmartUpload.Form(item)
                           if Trim(value) <> "" then                     
            body = body & item & ": " & value & newline
                                 End if
        Next
     Next
         If Trim(FileNameTitle) <> "" then
          body = body & "Attachment: " & FileNameTitle & newLine 
          body = body & "ContentType: " & ContentType & newLine
         End if
  
                 
    ' now destroy the smartupload object
    Set mySmartUpload=nothing
    
    ' remove the file that was uploaded by the web form
    Set fs=Server.CreateObject("Scripting.FileSystemObject")
    If fs.FileExists(Server.MapPath(tempLocation) & "\" & FileNameTitle) then
      fs.DeleteFile(Server.MapPath(tempLocation) & "\" & FileNameTitle)
       If fs.FileExists(Server.MapPath(tempLocation) & "\" & FileNameTitle) then
          body = body & "Web site failed to complete the removal of the application sent to you. Please login to the website and check htmlPages/upload/ for any excess files." & newline
         End if         
    End if
    Set fs = nothing             
                
                        
  JMail.Sender = From
  JMail.Subject = Subject
  JMail.AddRecipient YourEmailAddress
  JMail.Body = Body
  JMail.Priority = 3
  JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")
  JMail.Execute

If Err.Number <> 0 then  
   Response.Write("<table><tr><th colspan=2 align=left>Mail configuration Error.</th></tr>")
   Response.Write("<tr><td>Error #</td><td>" & CStr(Err.Number) & "</td></tr>")
   Response.Write("<tr><td>Error Description</td><td>" & Err.Description & "</td></tr>")
   Response.Write("<tr><td>JMail.Recipient:</td><td>" & YourEmailAddress & "</td></tr>")
   Response.Write("<tr><td>JMail.Sender:</td><td>" & JMail.Sender & "</td></tr>")        
   Response.Write("<tr><td>JMail.ServerAddress:</td><td>" & JMail.ServerAddress & "</td></tr>")
   Response.Write("<tr><td>JMail.Subject:</td><td>" & JMail.Subject & "</td></tr>")
   Response.Write("</table>")            
  Else

' Finally we need to transfer you to the finish page or drop a message letting you 
        ' know that we have completed the task.

If FinishPage <> "" then
      Err.Clear
      On Error Goto 0 ' turn off exception handling.
        Response.Redirect FinishPage
    Else    
      Response.Write("<h1>Thank You</h1><p>Your details have been submitted and you will be contacted shortly. Thank you</p>")
    End If

End if
  Err.Clear
  On Error Goto 0 ' turn off exception handling.

This script is currently incomplete and I would strongly recommend testing before adding it to a website.

Verbose Instructions

Do you want people to fill in a form on your web site, hit the submit button and have the details email to you? Want to attach a file, the you will need to use JMail and aspSmartupload.

This document has been broken down into the following sections:

What you will need before starting
The process involved.
The JMail script
Where to direct your form to
Where your email will be sent to
Which mail server to use
Testing the script
Completion

What you will need before starting

Before we start on adding the JMail script you will need a web form. Web forms are pages that allow you to fill in information and 'submit' those details to be processed. In this example will be filling in a web form and submitting those details for processing. Once the web form is processed the details are mailed across to an email address of your choosing.

Many web design programs allow you to develop forms on your web pages. If you are looking for an example form please visit the script-examples/smart-upload.htm page. More information about web forms can be found on the internet. Looking up the HTML tag "<forms>" will help you find out more information.

The process involved.

People can fill in the form then hit the submit button. This will pass the information from your form page to the mail script. Our script can then redirect the user to a 'thank you' page of your choosing. The script will display a short thank you message if you do not specify a finish page.

The JMail script

In order for the site to work will need a web page with a form on it, a copy of the above script, and a thank you page. While it is not necessary to do your script this way we will doing so in this example to help simplify the process involved.

To make the script you will need to copy the text from the text box near the top of this document.

To start with create a file call smart-upload.asp on your web site. Select all of the content from the text box above. Copy the contents of the text area and paste into a file called smart-upload.asp. Your web page editor should have documentation on how to do this if you do not know how. You will read through the code itself in order to setup the page correctly.

Where to direct your form to

When generating your web form you will need to keep in mind that this page will be sending information to another page. In order to post the information from one to another you will need to set 'action' field in the form to the ASP file we have created.

Where your email will be sent to

It is important to check that you have included valid data with this script. JMail will generate an email based on the information submitted to this page. If you have not included your email address in the 'YourEmailAddress' variable then the page will automatically send the email to web forms at your domain.

Which mail server to use

In order for your email to be submitted correctly your script will need to refer to a valid SMTP or outgoing mail server. Generally this is set to mail.example.com, where example.com is your registered domain name.

Acenet customers who are using this script with their home page may need to use mail.acenet.net.au

Testing the script

The next step involved is to test the script. Why not try emailing your self? Simply fill in your form using your email address and send the email. Please allow a couple of minutes for your email to make its way through the system. If your script did not generate any errors but you have not received an email within a hour you may need to check the Recipient address to ensure that a valid email address has been added.

Completion

Once you have checked and tested your script the site should now be ready to use. If everything went to plan you should have a fully functional form!

I would encourage you to try as many email addresses you have available to ensure that the script is working. While Acenet has made every effort to ensure the fidelity of the script, bug can occur. If you like you can contact webadmin@acenet.net.au for further help with your script. Please describe the problem you are having and include as much detail as possible. Please include your domain name,the web form's file name, the name of the ASP file which is processing the email and any error messages that have come up.

This make no sense

If you are finding that this script is difficult to follow or you know of a better way of doing this please let me know. This website is being updated continual so if you have any ideas, suggestions, gripes, annoyances, flaming arrows, etc. please contact me via email at webadmin@acenet.net.au

Telephone:	(07) 3899 1411	AcenetGlobal
Toll free:	1300 85 99 85	7/53 Metroplex Avenue
Facsimile:	(07) 3899 5174	Murarrie QLD 4172
ABN:	43 158 691 929	Email: webadmin@acenet.net.au